SQL Scripting

# JdbcCapitals.awk
BEGIN { FS = "\t"
    url = "jdbc:hsqldb:hsql://localhost/sampledb"
    print "CREATE TABLE COUNTRIES(" \
        "COUNTRY VARCHAR(30) NOT NULL, AREA INTEGER, POPULATION INTEGER, CONTINENT VARCHAR(30), " \
        "PRIMARY KEY ( COUNTRY ) )" |& url    # 表を作成
}
    {
    sql = "INSERT INTO COUNTRIES VALUES('" $1 "'," $2 "," $3 ",'" $4 "')"
    if (print sql |& url)    # 標準入力から読み込んだデータを表に追加
        print FNR, sql
}

# relfile: 問合せ命令(SQL)と列名(属性の別名)を定義
# #   注釈
# TABLE識別 :
#     属性(英字で始まる英数字) [ 別名(英字で始まる英数字または日本語) ] ...
#     ! データ抽出の前に実行する shell コマンド
#     ? データを抽出する SQL文
countries:
    country    国    ...
    area       面積
    population 人口
    continent  大陸
    ?SELECT * FROM COUNTRIES ORDER BY COUNTRY
 ...

# 4.3 関係データベース・システム: AWKもどきの問い合わせ言語q: page.139
BEGIN { url = ARGV[1]; ARGV[1] = ""
    readrel("relfile")    # 表定義ファイルの読み込み
    RS = ""        # 空行までを一つの問合せスクリプトとする
}
/./ { doquery($0) }

function readrel(f  ,i) {
    while (getline <f > 0) {            # parse relfile
        if ($0 ~ /^[ \t]*#/) {          # comment
        } else if ($0 ~ /^[A-Za-z]+ *:/) { # name:
            gsub(/[^A-Za-z]+/, "", $0)  # remove all but name
            relname[++nrel] = $0
        } else if ($0 ~ /^[ \t]*!/) {   # !command...
            cmd[nrel, ++ncmd[nrel]] = substr($0,index($0,"!")+1)
        } else if ($0 ~ /^[ \t]*\?/) {  # ?query SQL...
            $0 = substr($0,index($0,"?")+1)
            sub(/^[ \t]+/, " ")
            querySql[nrel] = querySql[nrel] $0
        } else if ($0 ~ /^[ \t]*[A-Za-z][A-Za-z0-9]*[ \t]*/) {
            attr[nrel, $1] = ++nattr[nrel]  # 属性(英字で始まる英数字)
            for (i = 2; i <= NF; i++)
                if ("" != $(i))    # 属性の別名(英字で始まる英数字または日本語)
                    attr[nrel, $(i)] = nattr[nrel]
        } else if ($0 !~ /^[ \t]*$/) {    # not white space
            print "bad line in relfile:", $0
        }
    }
}
function doquery(s,  q, i, j) {
    q = s
    for (i in qattr)    # clean up for next query
        delete qattr[i]
    query = s           # put $names in query into qattr, without $

    # 属性(英字で始まる英数字または日本語、プラットフォーム非依存とするため Unicodeで指定 u3041:ぁ fa2d:鶴)
    while (match(s, /\$[A-Za-z\u3041-\ufa2d][A-Za-z0-9\u3041-\ufa2d]*/)) {
        qattr[substr(s, RSTART+1, RLENGTH-1)] = 1
        s = substr(s, RSTART+RLENGTH+1)
    }
    for (i = 1; i <= nrel && !subset(qattr, attr, i); )
        i++
    if (i > nrel)        # didn't find a table with all attributes
        missing(qattr)
    else {               # table i contains attributes in query
        for (j in qattr) # create awk program
            gsub("\\$" j, "$" attr[i,j], query)
        for (j = 1; j <= ncmd[i]; j++)  # create table i
            if (system(cmd[i, j]) != 0) {
                print "command failed, query skipped\n", cmd[i,j]
                return
            }
        awkcmd = sprintf("%s -e '%s' '\"\"' -F='\\t' -vOFS='\\t' '%s;;%s'",
            ENVIRON["AWK4SQL"], query, url, querySql[i])
        system(awkcmd)    # AWK4J で問合せ
    }
}
function subset(q, a, r,  i) {    # is q a subset of a[r]?
    for (i in q)
        if (!((r,i) in a))
            return 0
        return 1
}
function missing(x,  i) {
    print "no table contains all of the following attributes:"
    for (i in x)
        print i
}